World of Video/World of Video.iso/programs/disk/diropus_uninstalled/installopus

Text File | 1995-02-13 | 4.4 KB | 214 lines

; Script to install Directory Opus version 4.12A+ for Amiga Plus
;
; DOpus Install Version    $VER: Install-Dopus 4.12A+ 1.11.94
;



    (complete 0)

; just in case the installation was restarted

    (makeassign "Dopus_Install" "")

; see if this is really an update



    (set is_update 0)
    (set DOPus_Dest (getassign "DOpus" "a"))


; if update, be sure they want program in same place

    (if DOPus_Dest
        (if    (askbool
                (prompt "There appears to be a current copy of Directory Opus "
                    "located in the drawer named \"" DOPus_Dest"\"."
                    "\n\nDo you want this version installed in that drawer?"
                )
                (help
                    "The installer has determined that you may already have a "
                    "copy of DOpus installed on your system. If this is wrong or "
                    "you want the update installed elsewhere, select NO as an "
                    "answer. Otherwise, select YES."
                )
            (default 1)
            )

; if user wants in same place

            (set is_update 1)

; if user wants in different place

            (set DOPus_Dest
                (tackon
                    (askdir
                        (prompt "Where should the DOpus Drawer be created?")
                        (help @askdir-help)
                        (default @default-dest)
                    )
                    "DOpus"
                )
            )
        )


; else if not an update, get a location for program
;
        (set DOPus_Dest
            (tackon
                (askdir
                    (prompt "Where should DOpus be installed?")
                    (help @askdir-help)
                    (default @default-dest)
                )
                "DOpus"
            )
        )
    )


; now lock on to Install Disk volume

;    (askdisk
;        (prompt "\nPlease insert the master program disk labeled \"DOpus_Install\".")
;        (help    "The DOpus program and other options will be copied "
;            "from the \"DOpus\" into your system.")
;        (dest  "DOpus")
;        (newname "Dopus_Install")
;    )

; make DOpus drawer & icon if not there

    (if     (not is_update)
            (makedir DOPus_Dest (infos))
    )

; at this point we have a valid destination, so we tell installer where
; the application will end up so the exit page will be correct -- also,
; the installation log file (if any) will be copied to the destination

    (set @default-dest DOPus_Dest)



    (working "\nWait...Cleaning Up old programs")

    (delete "S:DirectoryOpus.HLP")
    (delete "C:DOpusRT")
    (delete "C:ConfigOpus")
    (delete "Sys:ConfigOpus")
    (delete (tackon DOpus_Dest "ConfigOpus"))

    (complete 10)


    (set oldfile "Libs:Dopus.Library")
    (if    (= (exists oldfile) 1)
        (delete "Libs:Dopus.Library")
        (set libexists 1)
    )

    (set oldfile (tackon DOpus_Dest "Libs/DOpus.Library"))
    (if    (= (exists oldfile) 1)
        (delete "Libs:Dopus.Library")
        (set libexists 1)
    )

    (working "Reading the Install disk for Directory Opus files.")

    (copyfiles
        (prompt "About to install Directory Opus and support files")
        (help "Select the files or support directories and "
            "modules you wish to install with Directory Opus\n"
            @copyfiles-help
        )
        (source "Dopus_Install:")
        (dest DOpus_Dest)
        (pattern "(DirectoryOpus|C|Libs|Modules|S)")
        (infos)
        (confirm)
    )




(complete 80)



;Get the users startup choices
    (set mode (askchoice
            (prompt "Directory can be started automatically when you boot your computer. What do you wish to do?")
            (help    @askchoice-help    )
            (choices "Do not start Directory Opus on boot" "Start Directory Opus on boot" "Start Directory Opus Iconified")
            (default 0)
        )
    )


(complete 90)

; set the script for user startup
    (set commands (cat "ASSIGN DOpus: " "\""DOpus_Dest"\"\n"))

    (if (= mode 1)
        (set commands (cat commands "DOpus:DirectoryOpus\n"))
    )

    (if (= mode 2)
        (set commands (cat commands "DOpus:DirectoryOpus -i\n" newline))
    )



(complete 95)

; modify S:User-Startup


    (startup "DOpus"
        (prompt
        "The following instructions will added to your "
        "\"S:User-Startup\" so that your system will be properly "
        "configured to use DOpus.\n\n"
        commands)
        (help "This will add commands to your S:user-startup file to "
            "allow the correct operation of Directory Opus")
        (command commands)
    )


    (set text "Check out the ALL NEW Directory Opus 5!\n\n")
    (set text (cat text "Special upgrade offers available for existing\n"))
    (set text (cat text " DOpus users and for Amiga Plus readers.\n"))
    (set text (cat text "Contact your local GPSoftware distributor!"))

    (if libexists
        (set text (cat text "\n\nSince you already had DOpus installed,\nPlease REBOOT your computer."))
    )



;     reinitialize assigns

(if (not @pretend)
    (makeassign "DOpus" DOPus_Dest)

)



(complete 100)

; cleanup
(makeassign "Dopus_Install" (safe))

; bye bye HC

(exit text)